Copyright (c) 1994 J. Adams, W. Brainerd, J. Martin, and B. Smith.
All rights reserved.
This file may not be copied without permission of the authors.

59 Modules

Modules are nonexecutable program units that contain type definitions, object declarations, procedure definitions (module procedures), external procedure interfaces, user-defined generic names, and user-defined operators and assignments. Any such definitions not specified to be private to the module containing them are available to be shared with those programs that use the module. Thus modules provide a convenient sharing and encapsulation mechanism for data, types, procedures, and procedure interfaces.

Examples:

MODULE SHARED                           ! Making data objects
   COMPLEX GTX (100, 6)                 !   and a data type
   REAL, ALLOCATABLE :: Y(:), Z(:,:)    !   sharable via a module
   TYPE PEAK_ITEM
      REAL PEAK_VAL, ENERGY
      TYPE(PEAK_ITEM), POINTER :: NEXT
   END TYPE PEAK_ITEM
END MODULE SHARED

MODULE RATIONAL_ARITHMETIC              ! Defining a data
   TYPE RATIONAL; PRIVATE               !   abstraction for
      INTEGER NUMERATOR,DENOMINATOR     !   rational arithmetic
   END TYPE RATIONAL                    !   via a module
   INTERFACE ASSIGNMENT (=)             ! Generic extension of =
      MODULE PROCEDURE ERR, ERI, EIR
   END INTERFACE
   INTERFACE OPERATOR (+)               ! Generic extension of +
      MODULE PROCEDURE ARR, ARI, AIR
   END INTERFACE
      . . .
CONTAINS
   SUBROUTINE ERR (. . .)            ! A specific definition of =
      . . .
   FUNCTION ARR (. . .)              ! A specific definition of +
      . . .
END MODULE RATIONAL_ARITHMETIC

Related Topics:

Defined Type: Operators and Assignment
Defined Type: Objects
Host Association
Module Procedures
Program Units
PUBLIC and PRIVATE Attributes and Statements
USE Statement and Use Association

To Read More About It:

ISO 1539 : 1991, Fortran Standard, 2.2.4, 11.3, C.11.4
Fortran 90 Handbook, 0, 11.6
Programmer's Guide to Fortran 90, 7

A module is:

MODULE module-name
[ specification-part ]
[ CONTAINS
module-subprogram
[ module-subprogram ]...]

Things To Know:

1. A module does not contain executable code except the execution parts of any module subprograms.
2. The specification part of a module must not contain the following attributes or statements: ENTRY, FORMAT, INTENT, OPTIONAL, or statement function. Similarly, the specification part of a module must not contain automatic objects; all of these may appear in module procedures, however.
3. PUBLIC and PRIVATE attributes and statements are allowed only in the specification part of a module. PUBLIC specifies the designated entity as sharable by using program units. PRIVATE specifies the designated entity as not sharable but rather private within the module; such entities are fully shared and accessible among the module procedures of the module by host association.
4. A MODULE PROCEDURE statement may appear only in an interface block that has a generic specification. The interface block must be in a module that contains the procedure or in a host that accesses the module.
5. SAVE attributes and statements can be used in a module to preserve data values among uses of the module. If such values are to remain intact when all program units using the module are inactive, SAVE must be specified.
6. Module procedures are like internal procedures in that they access the host environment by host association as well as its implicit type mapping, but otherwise they are like external procedures.
7. Modules are ideal for data abstraction, generic procedure definition, operator extension, and the sharing of such information to all program